Algoritmos e Estruturas de Dados - Técnico em Informática para Internet - VisuALG - Aula 20/03/2013

Exercícios Resolvidos em Sala - VisuALG

No dia 20/03/2013 resolvemos diversos exercícios de algoritmos. Vimos como funciona a lógica de solução e finalmente, espero, começamos a entender a lógica de funcionamento dos algoritmos.

Abaixo os algoritmos feitos em sala de aula, resolvidos no VisuALG. É só copiar e colar no editor de pseudocódigo do VisuALG e pressionar F9 para executar, ou F8 para ver cada passo da execução e testar o funcionamento dos algoritmos.

EXERCÍCIOS RESOLVIDOS

1) Elaborar um algoritmo para calcular quantas vezes é possível subtrair 3 de 1000.
algoritmo "ex1_aula20032013"
// Função : quantas vezes é possível subtrair 3 de 1000?
// Autor :
// Data : 22/03/2013
// Seção de Declarações
var
  C, N: inteiro
inicio
// Seção de Comandos
  N <- 1000
  C <- 0
  enquanto N >= 3 faca
    N <- N - 3
    C <- C + 1
  fimenquanto
  escreva(C)
fimalgoritmo

2) Elaborar um algoritmo para calcular o quociente da divisão inteira entre N e D, valores inteiros fornecidos pelo usuário, sendo N maior que D, sabendo que o operador div não é uma primitiva (Uma função/operador que não uma primitiva da linguagem de programação é uma função que não está definida, ou seja, é como se ela não existisse, e portanto, 'N div D' não pode ser usado.).
algoritmo "ex2_aula20032013"
// Função : div não primitivo entre N e D (parecido com ex1_aula20032013)
// Autor :
// Data : 22/03/2013
// Seção de Declarações
var
  N, D, C: inteiro
inicio
// Seção de Comandos
  escreva("N: ")
  leia(N)
  escreva("D: ")
  leia(D)
  C <- 0
  enquanto N >= D faca
    N <- N - D
    C <- C + 1
  fimenquanto
  escreva(C)
fimalgoritmo

3) Elaborar um algoritmo para calcular o produto entre X e Y, valores inteiros fornecidos pelo usuário, sabendo que o operador * não é uma primitiva (Uma função/operador que não uma primitiva da linguagem de programação é uma função que não está definida, ou seja, é como se ela não existisse, e portanto, 'X * Y' não pode ser usado.).
algoritmo "ex3_aula20032013"
// Função : * não primitivo entre X e Y (parecido com ex2_aula20032013)
// Autor :
// Data : 22/03/2013
// Seção de Declarações
var
  X, Y, PROD: inteiro
inicio
// Seção de Comandos
  escreva("X: ")
  leia(X)
  escreva("Y: ")
  leia(Y)
  PROD <- 0
  enquanto X > 0 faca
    PROD <- PROD + Y // Soma Y, X vezes
    X <- X - 1
  fimenquanto
  escreva(PROD)
fimalgoritmo

4) Elaborar um algoritmo para determinar e imprimir os n primeiros termos de uma P.A. calculando-os sucessivamente, sendo que o usuário fornecerá n - a quantidade de termos, a₁ - termo inicial e r - razão.
algoritmo "ex4_aula20032013"
// Função : imprimir uma P.A.
// Autor :
// Data : 22/03/2013
// Seção de Declarações
var
  N, TERMO, RAZAO: inteiro
inicio
// Seção de Comandos
  escreva("N: ")
  leia(N)
  escreva("Termo inicial: ")
  leia(TERMO)
  escreva("Razao: ")
  leia(RAZAO)
  enquanto N > 0 faca
    escreva(TERMO)
    TERMO <- TERMO + RAZAO
    N <- N - 1
  fimenquanto
fimalgoritmo

5)  Elaborar um algoritmo para calcular a média de 12 faturamentos mensais.
algoritmo "ex5_aula20032013"
// Função : média de 12 faturamentos mensais
// Autor :
// Data : 22/03/2013
// Seção de Declarações
var
  FATMES, TOTAL: real
  N: inteiro
inicio
// Seção de Comandos
  TOTAL <- 0
  para N de 1 ate 12 faca
    escreva("Faturmento do mês ", N, ": ")
    leia(FATMES)
    TOTAL <- TOTAL + FATMES
  fimpara
  escreva("Média mensal = ", TOTAL / 12)
fimalgoritmo

TRABALHO EM GRUPO

Lembro que na próxima aula, dia 25/03/2013, teremos nosso trabalho em grupo, valendo 9,0 pontos. O trabalho servirá, também, de revisão para a prova que faremos no dia 27/03/2013, valendo 16,0 pontos. Os grupos serão formados em sala de aula e o trabalho não será repetido para quem faltar à aula, e nem poderá ser feito em separado e entregue depois. O trabalho será feito em sala e entregue ao final da aula. Essas das já haviam sido notificadas desde o dia 14/03/2013 através deste blog e antes dessa data em sala de aula, portanto, não há desculpas para perder o trabalho.